***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr. 08, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.SUBCKT  PJQ5443-AU  D  G  S
Rg     G    1t    1
EVgs 3 2t  TABLE { V(S, 1t) }
+((0, 0)
+ (0.5 , 0.5  )
+ (1   , 1    )
+ (1.5 , 1.5  )
+ (2   , 2    )
+ (2.5 , 2.5  )
+ (2.75, 2.80 )
+ (3   , 3.15 )
+ (4.5 , 4.85 )
+ (5   , 5.22 )
+ (8   , 8    )
+ (10  , 9.5  )
+ (20  , 16   )
+ (22  , 17   ))
EVgst 1 2t value = {1.687e-3*limit(v(2t,3),-5,0)*limit((temp-25),-80,125)}
M1      2    1    3    3    DMOS    L=1u   W=1u
.MODEL DMOS PMOS (
+  VTO = -1.86
+   KP = 32.2
+LEVEL =3)
Cgs    1t    3    4.317e-10
Rd      D    4    3.084e-3 tc=1.143e-2
Dds     4    3    DDS
.MODEL     DDS    D(IS=5.459E-12 N=1.065 RS=7.827e-3 eg=1.035 CJO=2.608e-10 M=4.390e-1 VJ=3.991e-1)
Dbody   D    3    DBODY
.MODEL   DBODY    D(IS=5.459E-12 N=1.065 RS=7.827e-3 eg=1.035 BV=44 IBV=250e-6 TBV1=8.406e-4 TT=25n)
Ra      4    2    2.033e-3
Rs      3    5    1e-4
Ls      5    S    0.001n
M2     1t    8    6    6   INTER
E2      8    6    4    1t   2
.MODEL   INTER    PMOS(VTO=0  KP=10   LEVEL=1)
Cgdmax  7    4    3.691e-10
Rcgd    7    4    10meg
Dgd     4    6    DGD
Rdgd    4    6    10meg
.MODEL     DGD    D(CJO=4.127e-10 M=3.629e-1 VJ=6.109e-1)
M3      7    9    1t    1t   INTER
E3      9    1t    4    1t   -2
.ENDS
*$
